lunaix-os/kernel/asm/x86/syscall.S

   1 #define __ASM__
   2 #include <lunaix/syscall.h>
   3
   4 .section .data
   5     /*
   6         注意，这里的顺序非常重要。每个系统调用在这个地址表里的索引等于其调用号。
   7     */
   8     syscall_table:
   9         1:
  10         .long 0
  11         .long __lxsys_fork          /* 1 */
  12         .long __lxsys_yield
  13         .long __lxsys_sbrk
  14         .long __lxsys_brk
  15         .long __lxsys_getpid        /* 5 */
  16         .long __lxsys_getppid
  17         .long __lxsys_sleep
  18         .long __lxsys_exit
  19         .long __lxsys_wait
  20         .long __lxsys_waitpid       /* 10 */
  21         .long __lxsys_sigreturn
  22         .long __lxsys_sigprocmask
  23         .long __lxsys_signal
  24         .long __lxsys_pause
  25         .long __lxsys_kill          /* 15 */
  26         .long __lxsys_alarm
  27         .long __lxsys_sigpending
  28         .long __lxsys_sigsuspend
  29         .long __lxsys_open
  30         .long __lxsys_close         /* 20 */
  31         .long __lxsys_read
  32         .long __lxsys_write
  33         .long __lxsys_readdir
  34         .long __lxsys_mkdir
  35         .long __lxsys_lseek          /* 25 */
  36         .long __lxsys_geterrno
  37         2:
  38         .rept __SYSCALL_MAX - (2b - 1b)/4
  39             .long 0
  40         .endr
  41
  42 .global syscall_hndlr
  43
  44 .section .text
  45     syscall_hndlr:
  46         pushl %ebp
  47         movl 8(%esp), %ebp
  48
  49         movl  (%ebp), %eax          /* eax: call code as well as the return value from syscall */
  50         cmpl  $__SYSCALL_MAX, %eax
  51         jae 2f
  52
  53         shll $2, %eax
  54         addl $syscall_table, %eax
  55         cmpl $0, (%eax)
  56         jne 1f
  57     2:
  58         neg   %eax
  59         popl  %ebp
  60         ret
  61     1:
  62         pushl 24(%ebp)      /* esi - #6 arg */
  63         pushl 20(%ebp)      /* ebp - #5 arg */
  64         pushl 16(%ebp)      /* edi - #4 arg */
  65         pushl 12(%ebp)      /* edx - #3 arg */
  66         pushl 8(%ebp)       /* ecx - #2 arg */
  67         pushl 4(%ebp)       /* ebx - #1 arg */
  68
  69         call (%eax)
  70
  71         movl %eax, (%ebp)    /* save the return value */
  72
  73         addl $24, %esp      /* remove the parameters from stack */
  74
  75         popl %ebp
  76
  77         ret