lunaix-os/kernel/asm/x86/syscall.S

   1 #define __ASM__
   2 #include <lunaix/syscall.h>
   3
   4 .section .data
   5     /*
   6         注意，这里的顺序非常重要。每个系统调用在这个地址表里的索引等于其调用号。
   7     */
   8     syscall_table:
   9         1:
  10         .long 0
  11         .long __lxsys_fork          /* 1 */
  12         .long __lxsys_yield
  13         .long __lxsys_sbrk
  14         .long __lxsys_brk
  15         .long __lxsys_getpid        /* 5 */
  16         .long __lxsys_getppid
  17         .long __lxsys_sleep
  18         .long __lxsys_exit
  19         .long __lxsys_wait
  20         .long __lxsys_waitpid       /* 10 */
  21         .long __lxsys_sigreturn
  22         .long __lxsys_sigprocmask
  23         .long __lxsys_signal
  24         .long __lxsys_pause
  25         .long __lxsys_kill          /* 15 */
  26         2:
  27         .rept __SYSCALL_MAX - (2b - 1b)/4
  28             .long 0
  29         .endr
  30
  31 .global syscall_hndlr
  32
  33 .section .text
  34     syscall_hndlr:
  35         pushl %ebp
  36         movl 8(%esp), %ebp
  37
  38         movl  (%ebp), %eax          /* eax: call code as well as the return value from syscall */
  39         cmpl  $__SYSCALL_MAX, %eax
  40         jae 2f
  41
  42         shll $2, %eax
  43         addl $syscall_table, %eax
  44         cmpl $0, (%eax)
  45         jne 1f
  46     2:
  47         neg   %eax
  48         popl  %ebp
  49         ret
  50     1:
  51         pushl 24(%ebp)      /* esi - #6 arg */
  52         pushl 20(%ebp)      /* ebp - #5 arg */
  53         pushl 16(%ebp)      /* edi - #4 arg */
  54         pushl 12(%ebp)      /* edx - #3 arg */
  55         pushl 8(%ebp)       /* ecx - #2 arg */
  56         pushl 4(%ebp)       /* ebx - #1 arg */
  57
  58         call (%eax)
  59
  60         movl %eax, (%ebp)    /* save the return value */
  61
  62         addl $24, %esp      /* remove the parameters from stack */
  63
  64         popl %ebp
  65
  66         ret