+++ /dev/null
-#define __ASM__
-#include <arch/x86/interrupts.h>
-#include <lunaix/common.h>
-#include <lunaix/syscall.h>
-#define __ASM_INTR_DIAGNOSIS
-
-.macro isr_template vector, no_error_code=1
- .global _asm_isr\vector
- .type _asm_isr\vector, @function
- _asm_isr\vector:
- .if \no_error_code
- pushl $0x0
- .endif
- pushl $\vector
- jmp interrupt_wrapper
-.endm
-
-#ifdef __ASM_INTR_DIAGNOSIS
-.section .bss
- .global debug_resv
- debug_resv:
- .skip 16
-#endif
-
-.section .text
- isr_template FAULT_DIVISION_ERROR
- isr_template FAULT_GENERAL_PROTECTION, no_error_code=0
- isr_template FAULT_PAGE_FAULT, no_error_code=0
-
- isr_template LUNAIX_SYS_PANIC
- isr_template LUNAIX_SYS_CALL
-
- isr_template APIC_ERROR_IV
- isr_template APIC_LINT0_IV
- isr_template APIC_TIMER_IV
- isr_template APIC_SPIV_IV
- isr_template RTC_TIMER_IV
- isr_template PC_KBD_IV
-
- interrupt_wrapper:
- /*
- Stack layout (layout of struct isr_param)
- msa: [ss]
- [esp]
- eflags > offset = 48 + 16 = 64
- cs
- eip
- err_code
- vector > offset = 28 + 16 + 4 = 48
- esp
- gs
- fs
- es
- ds > offset = 7 * 4 = 28
- esi
- ebp
- edi
- edx
- ecx
- ebx
- lsa: eax > offset = 0
-
- las: Least Significant Address
- msa: Most Significant Address
- */
- cld
- pushl %esp
-
- subl $16, %esp
- movw %gs, 12(%esp)
- movw %fs, 8(%esp)
- movw %es, 4(%esp)
- movw %ds, (%esp)
-
- pushl %esi
- pushl %ebp
- pushl %edi
- pushl %edx
- pushl %ecx
- pushl %ebx
- pushl %eax
-
- movl 60(%esp), %eax /* 取出 %cs */
- andl $0x3, %eax /* 判断 RPL */
- jz 1f
-
- movw $KDATA_SEG, %ax /* 如果从用户模式转来，则切换至内核数据段 */
- movw %ax, %gs
- movw %ax, %fs
- movw %ax, %ds
- movw %ax, %es
-
- # 保存用户栈顶指针。这是因为我们允许系统调用内进行上下文切换，而这样一来，我们就失去了用户栈的信息，
- # 这样一来，就无法设置信号上下文。这主要是为了实现了pause()而做的准备
- movl (__current), %eax
- movl 68(%esp), %ebx # 取出esp
- movl %ebx, 84(%eax) # 存入__current->ustack_top
-
- 1:
- movl %esp, %eax
- andl $0xfffffff0, %esp
- subl $16, %esp
- movl %eax, (%esp)
-
- call intr_handler
-
- .global soft_iret
- soft_iret:
- cli
- popl %esp
-
- popl %eax
- popl %ebx
- popl %ecx
- popl %edx
- popl %edi
- popl %ebp
- popl %esi
-
- movw (%esp), %ds
- movw 4(%esp), %es
- movw 8(%esp), %fs
- movw 12(%esp), %gs
-
- movl 16(%esp), %esp
-
- addl $8, %esp
-
-#ifdef __ASM_INTR_DIAGNOSIS
- pushl %eax
- movl 4(%esp), %eax
- movl %eax, debug_resv
- popl %eax
-#endif
- iret
-
- handle_signal:
- # 注意1：任何对proc_sig的布局改动，都须及时的保证这里的一致性！
- # 注意2：handle_signal在调用之前，须确保proc_sig已经写入用户栈！
- popl %eax # arg1: addr of proc_sig structure in user stack
- leal 8(%eax), %ebx
-
- pushl 72(%ebx) # proc_sig->prev_context.ss
- pushl %eax # esp
- pushl 64(%ebx) # proc_sig->prev_context.eflags
- pushl $UCODE_SEG # cs
- pushl $sig_wrapper # eip for sig wrapper
-
- movw $UDATA_SEG, %cx # switch data seg to user mode
- movw %cx, %es
- movw %cx, %ds
- movw %cx, %fs
- movw %cx, %gs
-
- iret
-
- sig_wrapper: # in user mode
- movl %esp, %eax
- and $0xfffffff0, %esp
- subl $8, %esp
- pushl %eax # Addr to proc_sig structure
- pushl 4(%eax) # proc_sig->sig_num ---- 16 bytes aligned
-
- call (%eax) # invoke signal handler
-
- # invoke the sigreturn syscall to exit the signal wrapper
- movl $__SYSCALL_sigreturn, %eax
- movl 4(%esp), %ebx
- int $LUNAIX_SYS_CALL
-
- ud2 # never reach!
\ No newline at end of file
git://scm.lunaixsky.com / lunaix-os.git / blobdiff