lunaix-os/kernel/asm/x86/syscall.S

   1 #define __ASM__
   2 #include <lunaix/syscall.h>
   3
   4 .section .data
   5     /*
   6         注意，这里的顺序非常重要。每个系统调用在这个地址表里的索引等于其调用号。
   7     */
   8     syscall_table:
   9         1:
  10         .long 0
  11         .long __lxsys_fork          /* 1 */
  12         .long __lxsys_yield
  13         .long __lxsys_sbrk
  14         .long __lxsys_brk
  15         .long __lxsys_getpid        /* 5 */
  16         .long __lxsys_getppid
  17         .long __lxsys_sleep
  18         .long __lxsys_exit
  19         .long __lxsys_wait
  20         .long __lxsys_waitpid       /* 10 */
  21         .long __lxsys_sigreturn
  22         .long __lxsys_sigprocmask
  23         .long __lxsys_signal
  24         .long __lxsys_pause
  25         .long __lxsys_kill          /* 15 */
  26         .long __lxsys_alarm
  27         .long __lxsys_sigpending
  28         .long __lxsys_sigsuspend
  29         .long __lxsys_open
  30         .long __lxsys_close
  31         // .long __lxsys_read
  32         // .long __lxsys_write
  33         .long __lxsys_readdir
  34         .long __lxsys_mkdir
  35         2:
  36         .rept __SYSCALL_MAX - (2b - 1b)/4
  37             .long 0
  38         .endr
  39
  40 .global syscall_hndlr
  41
  42 .section .text
  43     syscall_hndlr:
  44         pushl %ebp
  45         movl 8(%esp), %ebp
  46
  47         movl  (%ebp), %eax          /* eax: call code as well as the return value from syscall */
  48         cmpl  $__SYSCALL_MAX, %eax
  49         jae 2f
  50
  51         shll $2, %eax
  52         addl $syscall_table, %eax
  53         cmpl $0, (%eax)
  54         jne 1f
  55     2:
  56         neg   %eax
  57         popl  %ebp
  58         ret
  59     1:
  60         pushl 24(%ebp)      /* esi - #6 arg */
  61         pushl 20(%ebp)      /* ebp - #5 arg */
  62         pushl 16(%ebp)      /* edi - #4 arg */
  63         pushl 12(%ebp)      /* edx - #3 arg */
  64         pushl 8(%ebp)       /* ecx - #2 arg */
  65         pushl 4(%ebp)       /* ebx - #1 arg */
  66
  67         call (%eax)
  68
  69         movl %eax, (%ebp)    /* save the return value */
  70
  71         addl $24, %esp      /* remove the parameters from stack */
  72
  73         popl %ebp
  74
  75         ret