lunaix-os/link/lunaix.ldx

   1 #define __LD__
   2 #include "base.ldx"
   3
   4 ENTRY(ENTRY_POINT)
   5
   6 SECTIONS {
   7     . = LOAD_OFF;
   8
   9     #include <linking/boot_secs.ldx>
  10
  11     /* ---- kernel start ---- */
  12
  13     . += KEXEC_BASE;
  14
  15     PROVIDE(__kexec_text_start = ALIGN(PAGE_GRAN));
  16     __kexec_start = ALIGN(PAGE_GRAN);
  17
  18
  19     /* kernel executable sections */
  20
  21     #include "kernel.ldx"
  22
  23
  24     /* link-time allocated array */
  25
  26     #include "lga.ldx"
  27
  28
  29     /* All other stuff */
  30
  31     .ksymtable BLOCK(PAGE_GRAN) : AT ( ADDR(.ksymtable) - KEXEC_BASE )
  32     {
  33         *(.ksymtable)
  34     }
  35
  36     .bss BLOCK(PAGE_GRAN) : AT ( ADDR(.bss) - KEXEC_BASE )
  37     {
  38         *(.bss)
  39     }
  40
  41     .bss.kstack BLOCK(PAGE_GRAN) : AT ( ADDR(.bss.kstack) - KEXEC_BASE )
  42     {
  43         PROVIDE(__bsskstack_start = .);
  44
  45         *(.bss.kstack)
  46
  47         PROVIDE(__bsskstack_end = .);
  48     }
  49
  50     __kexec_end = ALIGN(PAGE_GRAN);
  51 }