lunaix-os/arch/i386/syscall.S

   1 #define __ASM__
   2 #include <lunaix/syscall.h>
   3
   4 .section .data
   5     /*
   6         注意，这里的顺序非常重要。每个系统调用在这个地址表里的索引等于其调用号。
   7     */
   8     syscall_table:
   9         1:
  10         .long 0
  11         .long __lxsys_fork          /* 1 */
  12         .long __lxsys_yield
  13         .long __lxsys_sbrk
  14         .long __lxsys_brk
  15         .long __lxsys_getpid        /* 5 */
  16         .long __lxsys_getppid
  17         .long __lxsys_sleep
  18         .long __lxsys_exit
  19         .long __lxsys_wait
  20         .long __lxsys_waitpid       /* 10 */
  21         .long __lxsys_sigreturn
  22         .long __lxsys_sigprocmask
  23         .long __lxsys_sys_sigaction
  24         .long __lxsys_pause
  25         .long __lxsys_kill          /* 15 */
  26         .long __lxsys_alarm
  27         .long __lxsys_sigpending
  28         .long __lxsys_sigsuspend
  29         .long __lxsys_open
  30         .long __lxsys_close         /* 20 */
  31         .long __lxsys_read
  32         .long __lxsys_write
  33         .long __lxsys_sys_readdir
  34         .long __lxsys_mkdir
  35         .long __lxsys_lseek         /* 25 */
  36         .long __lxsys_geterrno
  37         .long __lxsys_readlink
  38         .long __lxsys_readlinkat
  39         .long __lxsys_rmdir
  40         .long __lxsys_unlink        /* 30 */
  41         .long __lxsys_unlinkat
  42         .long __lxsys_link
  43         .long __lxsys_fsync
  44         .long __lxsys_dup
  45         .long __lxsys_dup2          /* 35 */
  46         .long __lxsys_realpathat
  47         .long __lxsys_symlink
  48         .long __lxsys_chdir
  49         .long __lxsys_fchdir
  50         .long __lxsys_getcwd        /* 40 */
  51         .long __lxsys_rename
  52         .long __lxsys_mount
  53         .long __lxsys_unmount
  54         .long __lxsys_getxattr
  55         .long __lxsys_setxattr      /* 45 */
  56         .long __lxsys_fgetxattr
  57         .long __lxsys_fsetxattr
  58         .long __lxsys_ioctl
  59         .long __lxsys_getpgid
  60         .long __lxsys_setpgid       /* 50 */
  61         .long __lxsys_syslog
  62         .long __lxsys_sys_mmap
  63         .long __lxsys_munmap
  64         .long __lxsys_execve
  65         .long __lxsys_fstat         /* 55 */
  66         .long __lxsys_pollctl
  67         2:
  68         .rept __SYSCALL_MAX - (2b - 1b)/4
  69             .long 0
  70         .endr
  71
  72 .global syscall_hndlr
  73
  74 .section .text
  75     syscall_hndlr:
  76         pushl %ebp
  77         movl 8(%esp), %ebp          // isr_param*
  78
  79         addl $4, %ebp
  80         movl (%ebp), %eax          /* eax: call code as well as the return value from syscall */
  81         cmpl $__SYSCALL_MAX, %eax
  82         jae 2f
  83
  84         shll $2, %eax
  85         addl $syscall_table, %eax
  86         cmpl $0, (%eax)
  87         jne 1f
  88     2:
  89         neg   %eax
  90         popl  %ebp
  91         ret
  92     1:
  93         pushl 24(%ebp)      /* esi - #5 arg */
  94         pushl 16(%ebp)      /* edi - #4 arg */
  95         pushl 12(%ebp)      /* edx - #3 arg */
  96         pushl 8(%ebp)       /* ecx - #2 arg */
  97         pushl 4(%ebp)       /* ebx - #1 arg */
  98
  99         call *(%eax)
 100
 101         movl %eax, (%ebp)    /* save the return value */
 102
 103         addl $20, %esp      /* remove the parameters from stack */
 104
 105         popl %ebp
 106
 107         ret