lunaix-os/kernel/asm/x86/interrupt.S

   1 #define __ASM__
   2 #include <arch/x86/interrupts.h>
   3 #include <lunaix/common.h>
   4 #include <lunaix/syscall.h>
   5 #define __ASM_INTR_DIAGNOSIS
   6
   7 #ifdef __ASM_INTR_DIAGNOSIS
   8 .section .bss
   9     .global debug_resv
  10     debug_resv:
  11         .skip 16
  12 #endif
  13
  14 .section .bss
  15     .align 16
  16     lo_tmp_stack:
  17         .skip 128
  18     tmp_stack:
  19
  20 .section .text
  21     .global interrupt_wrapper
  22     interrupt_wrapper:
  23         /*
  24          Stack layout (layout of struct isr_param)
  25     msa:   [ss]
  26            [esp]
  27            eflags     > offset = 48 + 16 = 64
  28            cs
  29            eip
  30            err_code
  31            vector     > offset = 28 + 16 + 4 = 48
  32            esp
  33            gs
  34            fs
  35            es
  36            ds         > offset = 7 * 4 = 28
  37            esi
  38            ebp
  39            edi
  40            edx
  41            ecx
  42            ebx
  43     lsa:   eax        > offset = 0
  44
  45             las: Least Significant Address
  46             msa: Most Significant Address
  47         */
  48         cld
  49         pushl %esp
  50
  51         subl $16, %esp
  52         movw %gs, 12(%esp)
  53         movw %fs,  8(%esp)
  54         movw %es,  4(%esp)
  55         movw %ds,   (%esp)
  56
  57         pushl %esi
  58         pushl %ebp
  59         pushl %edi
  60         pushl %edx
  61         pushl %ecx
  62         pushl %ebx
  63         pushl %eax
  64
  65         movl 60(%esp), %eax   /* 取出 %cs */
  66         andl $0x3, %eax          /* 判断 RPL */
  67         jz 1f
  68
  69         movw $KDATA_SEG, %ax    /* 如果从用户模式转来，则切换至内核数据段 */
  70         movw %ax, %gs
  71         movw %ax, %fs
  72         movw %ax, %ds
  73         movw %ax, %es
  74
  75         # 保存用户栈顶指针。这是因为我们允许系统调用内进行上下文切换，而这样一来，我们就失去了用户栈的信息，
  76         # 这样一来，就无法设置信号上下文。这主要是为了实现了pause()而做的准备
  77         movl (__current), %eax
  78
  79         # 保存x87FPU的状态
  80         movl 92(%eax), %ebx
  81         fxsave (%ebx)
  82
  83         movl 68(%esp), %ebx     # 取出esp
  84         movl %ebx, 84(%eax)     # 存入__current->ustack_top
  85
  86     1:
  87         movl %esp, %eax
  88         andl $0xfffffff0, %esp
  89         subl $16, %esp
  90         movl %eax, (%esp)
  91
  92         call intr_handler
  93
  94         movl (%esp), %eax
  95
  96     .global soft_iret
  97     soft_iret:
  98         movl %eax, %esp
  99
 100 #ifdef __ASM_INTR_DIAGNOSIS
 101         movl %eax, (debug_resv + 8)
 102         movl 56(%esp), %eax
 103         movl %eax, (debug_resv + 4)
 104 #endif
 105         movl (__current), %eax
 106         movl 92(%eax), %eax
 107
 108         test %eax, %eax     # do we have stored x87 context?
 109         jz 1f
 110         fxrstor (%eax)
 111 1:
 112         popl %eax
 113         popl %ebx
 114         popl %ecx
 115         popl %edx
 116         popl %edi
 117         popl %ebp
 118         popl %esi
 119
 120         movw   (%esp), %ds
 121         movw  4(%esp), %es
 122         movw  8(%esp), %fs
 123         movw 12(%esp), %gs
 124
 125         movl 16(%esp), %esp
 126
 127         addl $8, %esp
 128
 129         pushl %eax
 130 #ifdef __ASM_INTR_DIAGNOSIS
 131         movl 4(%esp), %eax
 132         movl %eax, debug_resv
 133 #endif
 134         # 处理TSS.ESP的一些边界条件。如果是正常iret（即从内核模式*优雅地*退出）
 135         # 那么TSS.ESP0应该为iret进行弹栈后，%esp的值。
 136         # 所以这里的边界条件是：如返回用户模式，iret会额外弹出8个字节（ss,esp）
 137         movl 8(%esp), %eax
 138         andl $3, %eax
 139         setnz %al
 140         shll $3, %eax
 141         addl $16, %eax
 142         addl %esp, %eax
 143         movl %eax, (_tss + 4)
 144         popl %eax
 145         iret
 146
 147     .global switch_to
 148     switch_to:
 149         # 约定
 150         # arg1: 目标进程PCB地址 (next
 151
 152         popl %ebx               # next
 153         movl __current, %eax
 154         movl 88(%eax), %ecx     # __current->pagetable
 155         movl 88(%ebx), %eax     # next->pagetable
 156
 157         cmpl %ecx, %eax         # if(next->pagtable != __current->pagetable) {
 158         jz 1f
 159         movl %eax, %cr3         #   cpu_lcr3(next->pagetable)
 160                                 # }
 161     1:
 162         movl %ebx, __current    # __current = next
 163
 164         # 我们已经处在了新的地址空间，为了避免影响其先前的栈布局
 165         # 需要使用一个临时的栈空间
 166         movl $tmp_stack, %esp
 167         call signal_dispatch    # kernel/signal.c
 168
 169         test %eax, %eax         # do we have signal to handle?
 170         jz 1f
 171         jmp handle_signal
 172     1:
 173         leal 8(%ebx), %eax
 174         jmp soft_iret
 175
 176     .global handle_signal
 177     handle_signal:
 178         # 注意1：任何对proc_sig的布局改动，都须及时的保证这里的一致性！
 179         # 注意2：handle_signal在调用之前，须确保proc_sig已经写入用户栈！
 180         leal 8(%eax), %ebx      # arg1 in %eax: addr of proc_sig structure in user stack
 181
 182         pushl $UDATA_SEG        # proc_sig->prev_context.proc_regs.ss
 183         pushl %eax              # esp
 184         pushl 64(%ebx)          # proc_sig->prev_context.proc_regs.eflags
 185         pushl $UCODE_SEG        # cs
 186         pushl $sig_wrapper      # eip for sig wrapper
 187
 188         movw $UDATA_SEG, %cx    # switch data seg to user mode
 189         movw %cx, %es
 190         movw %cx, %ds
 191         movw %cx, %fs
 192         movw %cx, %gs
 193
 194         iret
 195
 196 .section .usrtext
 197     sig_wrapper:                # in user mode
 198         movl %esp, %eax
 199         and $0xfffffff0, %esp
 200         subl $8, %esp
 201         pushl %eax              # Addr to proc_sig structure
 202         pushl 4(%eax)           # proc_sig->sig_num     ---- 16 bytes aligned
 203
 204         call (%eax)             # invoke signal handler
 205
 206         # invoke the sigreturn syscall to exit the signal wrapper
 207         movl $__SYSCALL_sigreturn, %eax
 208         movl 4(%esp), %ebx
 209         int $LUNAIX_SYS_CALL
 210
 211         ud2                     # never reach!