lunaix-os/kernel/asm/x86/interrupt.S

   1 #define __ASM__
   2 #include <arch/x86/interrupts.h>
   3 #include <lunaix/common.h>
   4 #include <lunaix/syscall.h>
   5 #define __ASM_INTR_DIAGNOSIS
   6
   7 #ifdef __ASM_INTR_DIAGNOSIS
   8 .section .bss
   9     .global debug_resv
  10     debug_resv:
  11         .skip 16
  12 #endif
  13
  14 .section .bss
  15     .align 16
  16     lo_tmp_stack:
  17         .skip 128
  18     tmp_stack:
  19
  20 .section .text
  21     .global interrupt_wrapper
  22     interrupt_wrapper:
  23         /*
  24          Stack layout (layout of struct isr_param)
  25     msa:   [ss]
  26            [esp]
  27            eflags     > offset = 48 + 16 = 64
  28            cs
  29            eip
  30            err_code
  31            vector     > offset = 28 + 16 + 4 = 48
  32            esp
  33            gs
  34            fs
  35            es
  36            ds         > offset = 7 * 4 = 28
  37            esi
  38            ebp
  39            edi
  40            edx
  41            ecx
  42            ebx
  43     lsa:   eax        > offset = 0
  44
  45             las: Least Significant Address
  46             msa: Most Significant Address
  47         */
  48         cld
  49         pushl %esp
  50
  51         subl $16, %esp
  52         movw %gs, 12(%esp)
  53         movw %fs,  8(%esp)
  54         movw %es,  4(%esp)
  55         movw %ds,   (%esp)
  56
  57         pushl %esi
  58         pushl %ebp
  59         pushl %edi
  60         pushl %edx
  61         pushl %ecx
  62         pushl %ebx
  63         pushl %eax
  64
  65         movl 60(%esp), %eax   /* 取出 %cs */
  66         andl $0x3, %eax          /* 判断 RPL */
  67         jz 1f
  68
  69         movw $KDATA_SEG, %ax    /* 如果从用户模式转来，则切换至内核数据段 */
  70         movw %ax, %gs
  71         movw %ax, %fs
  72         movw %ax, %ds
  73         movw %ax, %es
  74
  75         # 保存用户栈顶指针。这是因为我们允许系统调用内进行上下文切换，而这样一来，我们就失去了用户栈的信息，
  76         # 这样一来，就无法设置信号上下文。这主要是为了实现了pause()而做的准备
  77         movl (__current), %eax
  78         movl 68(%esp), %ebx     # 取出esp
  79         movl %ebx, 84(%eax)     # 存入__current->ustack_top
  80
  81     1:
  82         movl %esp, %eax
  83         andl $0xfffffff0, %esp
  84         subl $16, %esp
  85         movl %eax, (%esp)
  86
  87         call intr_handler
  88
  89         movl (%esp), %eax
  90
  91     .global soft_iret
  92     soft_iret:
  93         movl %eax, %esp
  94
  95 #ifdef __ASM_INTR_DIAGNOSIS
  96         movl %eax, (debug_resv + 8)
  97         movl 56(%esp), %eax
  98         movl %eax, (debug_resv + 4)
  99 #endif
 100
 101         popl %eax
 102         popl %ebx
 103         popl %ecx
 104         popl %edx
 105         popl %edi
 106         popl %ebp
 107         popl %esi
 108
 109         movw   (%esp), %ds
 110         movw  4(%esp), %es
 111         movw  8(%esp), %fs
 112         movw 12(%esp), %gs
 113
 114         movl 16(%esp), %esp
 115
 116         addl $8, %esp
 117
 118         pushl %eax
 119 #ifdef __ASM_INTR_DIAGNOSIS
 120         movl 4(%esp), %eax
 121         movl %eax, debug_resv
 122 #endif
 123         # 处理TSS.ESP的一些边界条件。如果是正常iret（即从内核模式*优雅地*退出）
 124         # 那么TSS.ESP0应该为iret进行弹栈后，%esp的值。
 125         # 所以这里的边界条件是：如返回用户模式，iret会额外弹出8个字节（ss,esp）
 126         movl 8(%esp), %eax
 127         andl $3, %eax
 128         setnz %al
 129         shll $3, %eax
 130         addl $16, %eax
 131         addl %esp, %eax
 132         movl %eax, (_tss + 4)
 133         popl %eax
 134         iret
 135
 136     .global switch_to
 137     switch_to:
 138         # 约定
 139         # arg1: 目标进程PCB地址 (next
 140
 141         popl %ebx               # next
 142         movl __current, %eax
 143         movl 88(%eax), %ecx     # __current->pagetable
 144         movl 88(%ebx), %eax     # next->pagetable
 145
 146         cmpl %ecx, %eax         # if(next->pagtable != __current->pagetable) {
 147         jz 1f
 148         movl %eax, %cr3         #   cpu_lcr3(next->pagetable)
 149                                 # }
 150     1:
 151         movl %ebx, __current    # __current = next
 152
 153         # 我们已经处在了新的地址空间，为了避免影响其先前的栈布局
 154         # 需要使用一个临时的栈空间
 155         movl $tmp_stack, %esp
 156         call signal_dispatch    # kernel/signal.c
 157
 158         test %eax, %eax         # do we have signal to handle?
 159         jz 1f
 160         jmp handle_signal
 161     1:
 162         leal 8(%ebx), %eax
 163         jmp soft_iret
 164
 165     .global handle_signal
 166     handle_signal:
 167         # 注意1：任何对proc_sig的布局改动，都须及时的保证这里的一致性！
 168         # 注意2：handle_signal在调用之前，须确保proc_sig已经写入用户栈！
 169         leal 8(%eax), %ebx      # arg1 in %eax: addr of proc_sig structure in user stack
 170
 171         pushl $UDATA_SEG        # proc_sig->prev_context.ss
 172         pushl %eax              # esp
 173         pushl 64(%ebx)          # proc_sig->prev_context.eflags
 174         pushl $UCODE_SEG        # cs
 175         pushl $sig_wrapper      # eip for sig wrapper
 176
 177         movw $UDATA_SEG, %cx    # switch data seg to user mode
 178         movw %cx, %es
 179         movw %cx, %ds
 180         movw %cx, %fs
 181         movw %cx, %gs
 182
 183         iret
 184
 185 .section .usrtext
 186     sig_wrapper:                # in user mode
 187         movl %esp, %eax
 188         and $0xfffffff0, %esp
 189         subl $8, %esp
 190         pushl %eax              # Addr to proc_sig structure
 191         pushl 4(%eax)           # proc_sig->sig_num     ---- 16 bytes aligned
 192
 193         call (%eax)             # invoke signal handler
 194
 195         # invoke the sigreturn syscall to exit the signal wrapper
 196         movl $__SYSCALL_sigreturn, %eax
 197         movl 4(%esp), %ebx
 198         int $LUNAIX_SYS_CALL
 199
 200         ud2                     # never reach!